Stiffy Makane: Apocolocyntosis — 123 of 235

Section Two - "Cleopatra"

Cleopatra is a woman in Cleopatra's Throne Room. The description is "Cleopatra is an astonishingly beautiful woman, with shoulder-length black hair with gold, beads, and jewels plaited into it. Her eyes are a startling violet under black kohl and heavy blue eyeshadow. [if the gown is worn by Cleopatra]She wears a green gown which exposes quite a bit of eye-popping cleavage, and[otherwise]She is resplendently naked, except for[end if] a golden bracelet in the form of a snake, which coils around her upper arm." The initial appearance of Cleopatra is "Cleopatra lounges on her throne, regarding you with mild interest and vague amusement." Understand "astonishing", "astonishingly", "beautiful", "pretty", "gorgeous", "queen", and "woman" as Cleopatra. The conversation of Cleopatra is the Table of Cleopatra's Chatter. The default reply of Cleopatra is "Cleopatra slowly blinks her gorgeous violet eyes, but says nothing." Cleopatra has a horniness. Cleopatra is unaroused. Instead of smelling Cleopatra, say "She smells wonderful." Understand "milf", "Cleo", "queen", and "pharoah" as Cleopatra. Does the player mean doing something with cleopatra: it is likely.

Instead of fucking, sucking, blowing, wanking off, touching, rubbing, kissing, or eating Cleopatra, follow the flirting-with-Cleopatra rule. Instead of buggering Cleopatra, try fucking Cleopatra's anus.

The green silk gown is a garment worn by Cleopatra. The description is "It's a simple olive drab silk gown, which probably cost more than your father's house. It exposes quite a bit of cleavage." Understand "simple", "expensive", "dress", "olive", "drab", and "olive-drab" as the green silk gown.

The golden snake bracelet is an ornament worn by Cleopatra. The description is "The bracelet is in the form of an asp, with amethyst eyes." Understand "amethyst", "gold", "jewel", "jeweled", and "asp" as the golden snake bracelet.

Some Cleopatra's breasts are part of Cleopatra. They are ambiguously plural. The indefinite article is "the pair of". The description is "[if the gown is worn by Cleopatra]You can see enough of Cleopatra's breasts to know you'd like to see more of them[otherwise]Utterly magnificent[end if]." Understand "chest", "eye-popping", "popping", "pair of", "magnificent", "utterly", "udderly" [1], "nipple", "nipples", "aureole", "aureoles", "aureola", "aureolae", "aureolas", "udder", "udders", "tits", "breast", "cleavage", "tit", "hooters", and "hooter" as Cleopatra's breasts. Check taking Cleopatra's breasts: instead try touching Cleopatra's breasts. Instead of kissing Cleopatra's breasts, try sucking Cleopatra's breasts. Instead of smelling Cleopatra's breasts, try smelling Cleopatra. They are proper-named.

Cleopatra's anus is an anus. The description is "[if the gown is worn by Cleopatra]It's gotta be under there somewhere[otherwise]Her pink ringpiece puckers invitingly[end if]." Understand "pink", "ringpiece", "puckered" as Cleopatra's anus. Instead of smelling Cleopatra's anus, say "It smells like roses. Really." Instead of kissing, rubbing, sucking, tasting, or eating Cleopatra's anus, try kissing Cleopatra's pussy. Instead of inserting the stiffycock into Cleopatra's anus, try fucking Cleopatra's anus. Instead of inserting something into Cleopatra's anus, say "Cleopatra grabs your wrist. 'Thanks,' she says, 'but I'd rather you actually did [italic type]not[roman type] put [a noun] in my ass.'"

Instead of buggering Cleopatra's anus, try fucking Cleopatra's anus. Check taking Cleopatra's anus: try fucking Cleopatra's anus.

Instead of fucking Cleopatra's anus:

if the stiffycock is not held by the player

begin;

say "You are not undressed for the occasion.";

stop the action;

end if;

say "Cleopatra pulls away slightly. 'I have other plans,' she gasps. 'I want to taste you.'";

try fucking Cleopatra's lips.

Cleopatra's pussy is a vagina. The description is "[if the gown is worn by Cleopatra]It's gotta be under there somewhere[otherwise]Her pussy is concealed in a thick, but neatly-trimmed, thatch of black pubic hair." Understand "musky", "intoxicating", "black", "pubic", "thatch", "curly", and "hair" as Cleopatra's pussy. Instead of inserting the stiffycock into Cleopatra's pussy, follow the flirting-with-Cleopatra rule. Instead of inserting something into Cleopatra's pussy, say "Cleopatra stops you. 'I don't think [a noun] is what I want in there,' she says[if the stiffycock is visible], staring at your [stiffycolor of the stiffycock]-glowing cock[end if]." Instead of fucking Cleopatra's pussy, follow the flirting-with-Cleopatra rule. Instead of smelling Cleopatra's pussy, say "Musky and intoxicating." Check taking Cleopatra's pussy: instead try fucking Cleopatra. Instead of kissing, rubbing, sucking, tasting, or eating Cleopatra's pussy:

say "Cleopatra moans and writhes under your caresses. [run paragraph on]";

if the stiffycock is not visible, instead say "She gasps, 'Undress. I want to taste you.'";

say "She hisses, 'I want to taste you.'";

try fucking Cleopatra's lips.

Instead of touching, rubbing, or squeezing Cleopatra's breasts:

if the gown is worn by Cleopatra, instead say "The green silk gown is in the way.";

follow the flirting-with-Cleopatra rule.

Instead of kissing, sucking, or tasting Cleopatra's breasts:

if the gown is worn by Cleopatra, instead try touching Cleopatra's breasts;

follow the flirting-with-Cleopatra rule.

Instead of fucking Cleopatra's breasts:

if the gown is worn by Cleopatra, instead try touching Cleopatra's breasts;

if the stiffycock is not visible, instead say "You are not undressed for the occasion.";

say "You begin thrusting between Cleopatra's perfect breasts. She licks her ruby-red lips, and, after a few minutes, murmurs,'I want to taste you.'";

try fucking Cleopatra's lips.

This is the flirting-with-Cleopatra rule:

if Cleopatra is boinked

begin;

say "Cleopatra smiles, but says, 'I have a kingdom to rule, you know. Run along, now.'";

stop the action;

end if;

if Cleopatra is unaroused

begin;

say "Cleopatra shrugs, in an I-don't-have-anything-better-to-do-right-now sort of way, and the two of you make out for a while. She pulls back and smiles. 'That seems pleasant enough,' she says. 'Let's adjourn to the bedroom.' She rises from the throne and steps through the bead curtain.";

really have the parser notice cleopatra;

move Cleopatra to Cleopatra's Boudoir;

now Cleopatra is horny;

now the initial appearance of Cleopatra is "Cleopatra sprawls naked on her bed.";

move the green silk gown to Limbo;

now Cleopatra's pussy is part of Cleopatra;

now Cleopatra's anus is part of Cleopatra;

otherwise;

if the stiffycock is not visible

begin;

say "Cleopatra raises an eyebrow quizzically. 'Aren't you a little overdressed?' she asks.";

otherwise;

say "Cleopatra kisses you passionately, and then guides you into her warm and wet pussy. You thrust enthusiastically for a while, and then Cleopatra places an exquisitely-manicured hand on your testes. 'I'd like to suck you off,' she murmurs.";

instead try fucking Cleopatra's lips;

end if;

end if.

Instead of showing the stiffycock to Cleopatra, say "Cleopatra is unimpressed, but she is slightly intrigued."

Cleopatra's violet eyes are a part of Cleopatra. They are ambiguously plural. The description is "You're not sure you've ever seen violet eyes before. But there they are." They are proper-named.

Cleopatra's blue eyeshadow is part of Cleopatra. The description is "It's very, very heavy blue eyeshadow. Somehow, she makes it look good." Understand "heavy" as Cleopatra's blue eyeshadow.

Cleopatra's black kohl is part of Cleopatra. The description is "Black kohl outlines her violet eyes." Understand "eyeliner" as Cleopatra's black kohl. It is proper-named.

Cleopatra's red lips are part of Cleopatra. The description is "Her ruby-red lips are moist and luscious." Understand "ruby", "ruby-red", "moist", "mouth", and "luscious" as Cleopatra's red lips.

Cleopatra's black hair is part of Cleopatra. The description is "Her hair is shoulder-length, intricately braided, with gold and jewels woven into it." Understand "shoulder", "shoulder-length", "braided", "intricate", "intricately", "gold", "golden", "braid", "jewel", and "jewels" as Cleopatra's black hair. It is proper-named.

Instead of fucking Cleopatra's lips:

if the stiffycock is not visible, instead say "You are not undressed for the occasion.";

if Cleopatra is unaroused, instead say "Cleopatra arches an eyebrow. 'Slow down there, tiger,' she says.";

if Cleopatra is boinked, instead say "'Thanks, but I've had enough for now.'";

say "You stand at the edge of the bed, and Cleopatra lies facing you. She runs her tongue lightly along your frenum, and then delicately takes the head of your cock into her luscious mouth.[paragraph break]";

say "Her eyes widen in surprise. She pulls back off your dick, grasping your manhood in beautifully-manicured fingers. 'You...you [italic type]taste[roman type] of him!' she exclaims. 'Oh, what a sweet, sweet gift for dear Caesar to give me!' The gorgeous eyes well with tears as she is briefly overcome with emotion.[paragraph break]";

say "Then she really sets to work, taking your cock all the way into her throat, over and over, your balls slapping against her exquisitely-formed chin. She kneads your buttocks with her hands. You tense as your orgasm builds, and she suddenly drives a finger deep into your ass. You groan as you explode inside her mouth, and after she has milked every last drop of semen from your clenching scrotum, she removes her digit and lets you sink to the floor.[paragraph break]";

say "Cleopatra belches delicately, and then wipes her eyes with a corner of the sheet. 'Thanks,' she says. 'That was great.' She sits up as you shakily get to your feet. Pulling you close, she kisses you deeply and violently, shoving your own sperm into your mouth with her tongue. Pulling back, she places a finger across your lips. 'If you see Gaius,' she whispers in your ear, 'give him [italic type]that[roman type] from me.'[paragraph break]";

if the toga is held or the toga is in Cleopatra's Boudoir

begin;

now the toga is worn by the player;

move the stiffycock to Limbo;

end if;

say "After a few minutes of desultory smalltalk, [if the toga is worn by the player]the two of you dress and[otherwise]she dresses and you both[end if] return to the throne room.";

now Cleopatra is boinked;

record "Cleopatra" as achieved;

move Cleopatra's pussy to Limbo;

move Cleopatra's anus to Limbo;

now the green silk gown is worn by Cleopatra;

now the initial appearance of Cleopatra is "Cleopatra lounges on her throne, regarding you fondly.";

really have the parser notice Cleopatra;

move Cleopatra to Cleopatra's Throne Room;

move the player to Cleopatra's Throne Room.

Before asking Cleopatra about something:

if Cleopatra is boinked

begin;

if the topic understood matches "Alexander/Alex/sarcophagus/coffin/tomb/mausoleum/soma/sepulcher/mummy" , replace the topic understood with "#fake1";

if the topic understood matches "Alexander the Great", replace the topic understood with "#fake1";

if the topic understood matches "Soma Mausoleum", replace the topic understood with "#fake1";

if the topic understood matches "sex", replace the topic understood with "#fake2";

end if;

if the sarcophagus is closed and the topic understood matches "#fake1"

begin;

say "Cleopatra claps her hands twice. An enormous Nubian enuch mumbers[33 as a footnote] into the room, bows deeply, and squeaks, 'What is your bidding, mistress?'";

say "[line break]Cleopatra says 'This man,' nodding at you, 'desires to see Alexander's body. Open the sarcophagus.'";

say "[line break]'As you wish,' chirps the eunuch, abases himself before Cleopatra, and mumbers backwards (quite a sight) to the south. After a moment, you hear the scraping of stone on stone from far away. Cleopatra smiles beatifically.";

now the sarcophagus is open;

end if.

Table of Cleopatra's Chatter