Stiffy Makane: Apocolocyntosis — 61 of 235

Chapter Five - "Privy"

Section One - "Privy"

The privy is a room. "This is the privy. It's actually quite nice by local standards, having a wooden seat over a hole that drops down to the sewer system below. [if the flimsy door is open]An open door to the south[otherwise]A crescent-shaped cut-out in the door[end if] provides light and ventilation." The Peristyle is outside from the privy.

The toilet is scenery in the privy. The description is "A polished wooden seat frames the drop into darkness. When you were little, you often feared you'd fall through into the sewers. Even these days, you could probably squeeze down there if you really wanted to." It is a supporter. Understand "privy", "hole", "drop", "dark", "darkness", "sewer", "sewers", "polished", "wood", "wooden", and "seat" as the toilet. Instead of searching the toilet, say "Rusted iron rungs concealed under the seat descend into the sewers." The toilet can be enterable. The toilet is enterable. Instead of going inside in the privy, try entering the toilet.

Instead of pissing in the privy:

follow the gotta-pee rule;

if the rule failed, stop the action;

say "You relieve yourself into the toilet. Aaaah.";

now the last_pissing_turn is the turn count.

Instead of shitting in the privy:

follow the gotta-poop rule;

if the rule failed, stop the action;

if the player is not on the toilet

begin;

say "(first sitting on the toilet)";

now the player is on the toilet;

end if;

say "You shit blissfully into the darkness beneath the toilet, enjoying the gentle splash of turds into the sewer.";

now the last_shitting_turn is the turn count.

Instead of inserting anything into the toilet:

if the privy is not warned_about

begin;

say "Anything you drop down there is likely gone forever.";

now the privy is warned_about;

otherwise;

if the noun is the signet ring and the Poop Deck is not warned_about

begin;

say "That would be exceptionally stupid.";

stop the action;

end if;

say "You hear a faint splash followed by a forlorn 'bloop.'";

move the noun to Limbo;

really have the parser notice the privy;

if the noun is the toga

begin;

say "(You can always ask Festus to bring you a new toga.)";

end if;

if the noun is the iron key and the iron grate is locked

begin;

say "There's a sharp spitting noise from beneath, and the iron key sails up through the toilet to land on the floor.";

move the iron key to the location;

really have the parser notice the iron key;

end if;

if the noun is the invitation token

begin;

say "You hear a glutinous chuckle from the sewers, and your father's signet ring sails up through the toilet to land, clinking, on the floor.";

move the signet ring to the location;

really have the parser notice the signet ring;

end if;

end if.

Carry out going down in the privy:

say "You slither into the toilet and take hold of the ladder.";

if Stiffy Makane is not filthy, say "With rue, but without surprise, you note that you have gotten absolutely filthy.";

now Stiffy Makane is filthy;

now every garment worn by Stiffy Makane is filthy;

now every garment carried by Stiffy Makane is filthy;

continue the action;

The iron ladder is a backdrop in the privy. It is in Beneath the privy. The description is "Rusty iron rungs [if the location is the privy]descend into smelly darkness[otherwise]ascend to the privy[end if]." Understand "rusty", "rung", "rungs", and "iron" as the ladder. Instead of climbing the ladder:

if the location is the privy, instead try going down;

if the location is Beneath the Privy, instead try going up.