Stiffy Makane: Apocolocyntosis — 19 of 235

Part Seven - "Stiffy Makane"

Stiffy Makane is a man. He is in the Battlement. The description is "Stiffy Makane (Mentula Macanus[5 as a footnote]): perhaps not the noblest Roman of them all[3 as a reference], but certainly one of the better-hung[if Stiffy Makane is filthy]. Also one of the more-covered-in-sewage, alas[end if]." Understand "Mentula", "Macanus", and "Mentula Macanus" as Stiffy Makane. Check sucking Stiffy Makane: instead try blowing Stiffy Makane. Stiffy Makane has a cleanliness. Stiffy Makane is cleanish. Stiffy Makane is unspeakable [1]. The default reply of Stiffy Makane is "Talking to yourself is said to be a sign of impending mental collapse[71 as a reference]." Stiffy Makane has a number called coldness. The coldness of Stiffy Makane is 0. Does the player mean taking Stiffy Makane when the player is Stiffy Makane: it is very unlikely. Does the player mean fucking Stiffy Makane when the player is Stiffy Makane: it is very unlikely.

Check fucking Stiffy Makane:

instead try blowing Stiffy Makane.

The toga is a garment. Stiffy Makane is wearing the toga. The description of the toga is "A plain white linen toga, as befits a Roman citizen[if the toga is filthy], although currently repulsively filthy[end if]." Check rolling the toga: instead say "There's really no compelling reason to roll up the toga."

Check blowing Stiffy Makane:

if the stiffycock is diseased

begin;

say "Even if you could, which you can't, given its current state, you really wouldn't want to.";

otherwise;

say "If you could do that, you'd never leave your house.";

end if;

stop the action.

Check inserting the golden banana into Stiffy Makane when the player is Stiffy Makane:

say "The effort required to hold something that heavy in place, combined with the coldness of the metal, and the fact that even though a unique holy relic, it would also be an uncomfortable hunk of metal up your ass[89 as a reference], dissuades you.";

stop the action.

Check inserting the sausage into Stiffy Makane when the player is Stiffy Makane:

instead try taking the sausage.

Check inserting something into Stiffy Makane when the player is Stiffy Makane:

if the noun is the stiffycock or the noun is Stiffy Makane, instead try fucking Stiffy Makane;

if the noun is not held by Stiffy Makane, instead say "The logistics of this act are beyond you.";

if the noun is a garment, instead say "That'd be an awful lot to cram up there.";

instead say "After some consideration, you decide not to attempt insertion of [the noun] into your rectum. Sometimes things slip from your grasp when you do that, and then it's always really embarassing getting help to retrieve them."

Stiffy Makane's anus is a part of Stiffy Makane. It is an anus. The description is "Although it has received many compliments, your anus is rather hard for you to see without a mirror." Instead of smelling Stiffy Makane's anus, say "That would be a lot of contortion for a very dubious benefit." Instead of tasting, sucking, or kissing Stiffy Makane's anus, try smelling Stiffy Makane's anus. Instead of searching Stiffy Makane's anus, say "You're sure there's nothing out of the ordinary hidden inside." Instead of touching or rubbing Stiffy Makane's anus, say "You don't need to touch it to know it's still there." Instead of inserting anything into Stiffy Makane's anus, try inserting the noun into Stiffy Makane.

Stiffycolor is a kind of value. The stiffycolors are blue, green, yellow, orange, red, purple, indigo, violet, crimson, pallid gray, ochre, silvery-white, chartreuese, hot pink, teal, moss rose, salmon, iridescent turquoise, toxic orange, burnt umber, magenta, sort of leprous mottled greenish-brown, and fuliginous ultraviolet.

The stiffycock is a penis. The stiffycock has a stiffycolor. The stiffycock is blue. Understand "stiffy" as stiffycock. The printed name is "cock". The indefinite article of the stiffycock is "your". Does the player mean doing something with the stiffycock: it is unlikely.

Cockglow is a number that varies. Cockglow is 0.

To suppress the inventory information:

(- c_style = c_style &~ (FULLINV_BIT+PARTINV_BIT); -).

Rule for printing the name of the stiffycock while taking inventory:

suppress the inventory information;

say "[if the stiffycock is diseased]diseased [end if]penis[if the stiffycock is lit] (glowing with a faint [stiffycolor] glow)[end if]".

After examining the stiffycock for the second time:

if the stiffycock is not lit

begin;

say "Are you looking for something different here? It hasn't changed, you know.";

otherwise;

say "The glow is a bit alarming, but otherwise, same old same old. Are you fishing for a particular response here?";

end if;

After examining the stiffycock for the third time: say "Oh, all right: 'Your stiffy is big and greasy [4 as a reference].' Are you happy now?"

After examining the stiffycock:

if cockglow is 1

begin;

say "You note with disappointment that your penis is no longer glowing.";

now cockglow is 2;

end if.

The description is "The root [if the stiffycock is lit](faintly glowing [stiffycolor]) [end if]of all existence, at least for you.[if the stiffycock is diseased] The discharge of greenish pus is kind of scary, though.[end if]". Check dropping the stiffycock: instead say "The Makane clan has not yet evolved the ability for male Makanes to drop their penes. Check back in a couple millennia[5 as a reference]." Check blowing the stiffycock: instead try blowing the player. Check sucking the stiffycock: try blowing the player. Understand "penis" as stiffycock. Check taking the stiffycock:

if the stiffycock is held, instead try rubbing the stiffycock;

say "BUG! How did you get here?";

stop the action.

Check giving the stiffycock to a person (called the penetratee): instead try fucking the penetratee. Check inserting the stiffycock into something (called the penetratee): instead try fucking the penetratee. Check attacking something (called the penetratee) with the stiffycock: instead try fucking the penetratee.

Check smelling the stiffycock:

If the stiffycock is diseased, instead try smelling the greenish pus;

If Stiffy Makane is cleanish, instead say "Vaguely cheesy. Probably time to hit the baths.";

If Stiffy Makane is sparkling, instead say "Your cock smells fresh and clean, if slightly soapy.";

say "Your cock, like the rest of you, is covered in ordure. There's no point in smelling it."

Check tasting the stiffycock: instead try sucking the stiffycock. Check touching the stiffycock: instead try wanking. Check eating the stiffycock: instead try sucking the stiffycock. Check rubbing the stiffycock: instead try wanking. Check pulling the stiffycock: instead try wanking. Check squeezing the stiffycock: instead try wanking.

Check putting the stiffycock on a supporter (called the cockrest): instead say "You smack your penis down onto [the cockrest]. [if the stiffycock is diseased]OW![otherwise]Classy.[end if]"

Some greenish pus is a thing. Understand "green", "gonorrhea", "painful", "drip", "drips", "std", "drippy", "burning", and "discharge" as greenish pus. The description is "A painful, greenish discharge drips from your cock." Check kissing the greenish pus: instead try squeezing the greenish pus. Check eating the greenish pus: instead try squeezing the greenish pus. Check tasting the greenish pus: instead try squeezing the greenish pus. Check rubbing the greenish pus: instead try squeezing the greenish pus. Check drinking the greenish pus: instead try squeezing the greenish pus. Check touching the greenish pus: instead try squeezing the greenish pus. Check squeezing the greenish pus: instead say "Not gonna touch it." Check smelling the greenish pus: instead say "Ew." Check showing the greenish pus to someone (called the observer): instead try showing the stiffycock to the observer. Check giving the greenish pus to someone (called the observer): instead try giving the stiffycock to the observer. Check dropping the greenish pus: instead say "You shake some off, but more just dribbles out."

Some feet are parts of Stiffy Makane. They are ambiguously plural. The description of the feet is "You know what they say about men with big feet? Well, in this case, it happens to be true[if the coldness of Stiffy Makane is greater than 49]. Well, not [italic type]right[roman type] now, because of the cold, but in general[end if]." Understand "foot" as feet.